corrade-lsl-templates – Rev 36
?pathlinks?
///////////////////////////////////////////////////////////////////////////
// Copyright (C) Wizardry and Steamworks 2016 - License: CC BY 2.0 //
///////////////////////////////////////////////////////////////////////////
//
// This script is a simple teleport button that makes Corrade teleport to
// your current location.
//
// For more information on Corrade, please see:
// http://grimore.org/secondlife/scripted_agents/corrade
//
///////////////////////////////////////////////////////////////////////////
///////////////////////////////////////////////////////////////////////////
// Copyright (C) 2015 Wizardry and Steamworks - License: CC BY 2.0 //
///////////////////////////////////////////////////////////////////////////
string wasKeyValueGet(string k, string data) {
if(llStringLength(data) == 0) return "";
if(llStringLength(k) == 0) return "";
list a = llParseString2List(data, ["&", "="], []);
integer i = llListFindList(llList2ListStrided(a, 0, -1, 2), [ k ]);
if(i != -1) return llList2String(a, 2*i+1);
return "";
}
///////////////////////////////////////////////////////////////////////////
// Copyright (C) 2013 Wizardry and Steamworks - License: CC BY 2.0 //
///////////////////////////////////////////////////////////////////////////
string wasKeyValueEncode(list data) {
list k = llList2ListStrided(data, 0, -1, 2);
list v = llList2ListStrided(llDeleteSubList(data, 0, 0), 0, -1, 2);
data = [];
do {
data += llList2String(k, 0) + "=" + llList2String(v, 0);
k = llDeleteSubList(k, 0, 0);
v = llDeleteSubList(v, 0, 0);
} while(llGetListLength(k) != 0);
return llDumpList2String(data, "&");
}
///////////////////////////////////////////////////////////////////////////
// Copyright (C) 2015 Wizardry and Steamworks - License: CC BY 2.0 //
///////////////////////////////////////////////////////////////////////////
// escapes a string in conformance with RFC1738
string wasURLEscape(string i) {
string o = "";
do {
string c = llGetSubString(i, 0, 0);
i = llDeleteSubString(i, 0, 0);
if(c == "") jump continue;
if(c == " ") {
o += "+";
jump continue;
}
if(c == "\n") {
o += "%0D" + llEscapeURL(c);
jump continue;
}
o += llEscapeURL(c);
@continue;
} while(i != "");
return o;
}
///////////////////////////////////////////////////////////////////////////
// Copyright (C) 2015 Wizardry and Steamworks - License: CC BY 2.0 //
///////////////////////////////////////////////////////////////////////////
// unescapes a string in conformance with RFC1738
string wasURLUnescape(string i) {
return llUnescapeURL(
llDumpList2String(
llParseString2List(
llDumpList2String(
llParseString2List(
i,
["+"],
[]
),
" "
),
["%0D%0A"],
[]
),
"\n"
)
);
}
// callback URL
string callback = "";
// configuration data
string configuration = "";
default {
state_entry() {
llSetTimerEvent(1);
}
link_message(integer sender, integer num, string message, key id) {
if(sender != 1 || id != "configuration") return;
configuration = message;
state off;
}
timer() {
llMessageLinked(LINK_ROOT, 0, "configuration", NULL_KEY);
}
attach(key id) {
llResetScript();
}
on_rez(integer num) {
llResetScript();
}
changed(integer change) {
if((change & CHANGED_INVENTORY) || (change & CHANGED_REGION_START)) {
llResetScript();
}
}
state_exit() {
llSetTimerEvent(0);
}
}
state off {
state_entry() {
llReleaseControls();
llSetColor(<.5,0,0>, ALL_SIDES);
}
touch_end(integer num) {
state on;
}
attach(key id) {
llResetScript();
}
on_rez(integer num) {
llResetScript();
}
}
state on {
state_entry() {
llSetColor(<0,.5,0>, ALL_SIDES);
state url;
}
attach(key id) {
llResetScript();
}
on_rez(integer num) {
llResetScript();
}
}
state url {
state_entry() {
// DEBUG
llOwnerSay("Requesting URL...");
llRequestURL();
}
touch_end(integer num) {
llSetColor(<.5,0,0>, ALL_SIDES);
llResetScript();
}
http_request(key id, string method, string body) {
if(method != URL_REQUEST_GRANTED) return;
callback = body;
// DEBUG
llOwnerSay("Got URL...");
state teleport;
}
attach(key id) {
llResetScript();
}
on_rez(integer num) {
llResetScript();
}
changed(integer change) {
if((change & CHANGED_INVENTORY) || (change & CHANGED_REGION_START)) {
llResetScript();
}
}
}
state teleport {
state_entry() {
// DEBUG
llOwnerSay("Teleporting...");
/*
* These calculations achieve the following:
* - teleport Corrade in front of you at a distance the size of your bounding box,
* - make Corrade turn towards 1m in front of its position after the teleport
* The reason for doing this is that radar object detection is dependent on the
* position that Corrade is facing.
*/
// Get the avatar global position and rotation.
list details = llGetObjectDetails(llGetOwner(), [OBJECT_POS, OBJECT_ROT]);
// Extract the position and rotation.
vector pos = llList2Vector(details, 0);
quaternion rot = llList2Rot(details, 1);
// Compute the scale of the avatar (side of cuboid).
list box = llGetBoundingBox(llGetOwner());
vector a = llList2Vector(box, 0);
vector b = llList2Vector(box, 1);
float size = b.x - a.x;
vector position = <size, 0, 0> * rot + llGetPos();
vector lookAt = (<1, 0, 0> + <size, 0, 0>) * rot + llGetPos();
llInstantMessage(
(key)wasKeyValueGet(
"corrade",
configuration
),
wasKeyValueEncode(
[
"command", "teleport",
"group", wasURLEscape(
wasKeyValueGet(
"group",
configuration
)
),
"password", wasURLEscape(
wasKeyValueGet(
"password",
configuration
)
),
"entity", "region",
"region", wasURLEscape(
llGetRegionName()
),
"deanimate", "True",
"position", wasURLEscape((string)position),
"turnto", wasURLEscape((string)lookAt),
"callback", wasURLEscape(callback)
]
)
);
llSetTimerEvent(60);
}
timer() {
// DEBUG
llOwnerSay("Teleport failed...");
llSetColor(<.5,0,0>, ALL_SIDES);
llResetScript();
}
touch_end(integer num) {
llSetColor(<.5,0,0>, ALL_SIDES);
llResetScript();
}
http_request(key id, string method, string body) {
llHTTPResponse(id, 200, "OK");
if(wasKeyValueGet("command", body) != "teleport" ||
wasKeyValueGet("success", body) != "True") {
// DEBUG
llOwnerSay("Teleport failed with failure message: " +
wasURLUnescape(
wasKeyValueGet(
"data",
body
)
)
);
llSetColor(<.5,0,0>, ALL_SIDES);
llResetScript();
}
// DEBUG
llOwnerSay("Teleport succeeded...");
llSetColor(<.5,0,0>, ALL_SIDES);
llResetScript();
}
attach(key id) {
llResetScript();
}
on_rez(integer num) {
llResetScript();
}
changed(integer change) {
if((change & CHANGED_INVENTORY) || (change & CHANGED_REGION_START)) {
llResetScript();
}
}
state_exit() {
llSetTimerEvent(0);
}
}
Generated by GNU Enscript 1.6.5.90.