| /source/eggdrop/stitch.lsl |
|---|
| @@ -0,0 +1,528 @@ |
|---|
| /////////////////////////////////////////////////////////////////////////// |
| // Copyright (C) Wizardry and Steamworks 2016 - License: GNU GPLv3 // |
| /////////////////////////////////////////////////////////////////////////// |
| // |
| // A module that upgrades or downgrades Corrade via Stitch. |
| // |
| /////////////////////////////////////////////////////////////////////////// |
| |
| /////////////////////////////////////////////////////////////////////////// |
| // Copyright (C) 2014 Wizardry and Steamworks - License: GNU GPLv3 // |
| /////////////////////////////////////////////////////////////////////////// |
| string wasKeyValueGet(string k, string data) { |
| if(llStringLength(data) == 0) return ""; |
| if(llStringLength(k) == 0) return ""; |
| list a = llParseString2List(data, ["&", "="], []); |
| integer i = llListFindList(a, [ k ]); |
| if(i != -1) return llList2String(a, i+1); |
| return ""; |
| } |
| |
| /////////////////////////////////////////////////////////////////////////// |
| // Copyright (C) 2013 Wizardry and Steamworks - License: GNU GPLv3 // |
| /////////////////////////////////////////////////////////////////////////// |
| string wasKeyValueEncode(list data) { |
| list k = llList2ListStrided(data, 0, -1, 2); |
| list v = llList2ListStrided(llDeleteSubList(data, 0, 0), 0, -1, 2); |
| data = []; |
| do { |
| data += llList2String(k, 0) + "=" + llList2String(v, 0); |
| k = llDeleteSubList(k, 0, 0); |
| v = llDeleteSubList(v, 0, 0); |
| } while(llGetListLength(k) != 0); |
| return llDumpList2String(data, "&"); |
| } |
| |
| /////////////////////////////////////////////////////////////////////////// |
| // Copyright (C) 2011 Wizardry and Steamworks - License: GNU GPLv3 // |
| /////////////////////////////////////////////////////////////////////////// |
| // http://was.fm/secondlife/wanderer |
| vector wasCirclePoint(float radius) { |
| float x = llPow(-1, 1 + (integer) llFrand(2)) * llFrand(radius*2); |
| float y = llPow(-1, 1 + (integer) llFrand(2)) * llFrand(radius*2); |
| if(llPow(x,2) + llPow(y,2) <= llPow(radius,2)) |
| return <x, y, 0>; |
| return wasCirclePoint(radius); |
| } |
| |
| /////////////////////////////////////////////////////////////////////////// |
| // Copyright (C) 2015 Wizardry and Steamworks - License: GNU GPLv3 // |
| /////////////////////////////////////////////////////////////////////////// |
| // escapes a string in conformance with RFC1738 |
| string wasURLEscape(string i) { |
| string o = ""; |
| do { |
| string c = llGetSubString(i, 0, 0); |
| i = llDeleteSubString(i, 0, 0); |
| if(c == "") jump continue; |
| if(c == " ") { |
| o += "+"; |
| jump continue; |
| } |
| if(c == "\n") { |
| o += "%0D" + llEscapeURL(c); |
| jump continue; |
| } |
| o += llEscapeURL(c); |
| @continue; |
| } while(i != ""); |
| return o; |
| } |
| |
| /////////////////////////////////////////////////////////////////////////// |
| // Copyright (C) 2015 Wizardry and Steamworks - License: GNU GPLv3 // |
| /////////////////////////////////////////////////////////////////////////// |
| list wasCSVToList(string csv) { |
| list l = []; |
| list s = []; |
| string m = ""; |
| do { |
| string a = llGetSubString(csv, 0, 0); |
| csv = llDeleteSubString(csv, 0, 0); |
| if(a == ",") { |
| if(llList2String(s, -1) != "\"") { |
| l += m; |
| m = ""; |
| jump continue; |
| } |
| m += a; |
| jump continue; |
| } |
| if(a == "\"" && llGetSubString(csv, 0, 0) == a) { |
| m += a; |
| csv = llDeleteSubString(csv, 0, 0); |
| jump continue; |
| } |
| if(a == "\"") { |
| if(llList2String(s, -1) != a) { |
| s += a; |
| jump continue; |
| } |
| s = llDeleteSubList(s, -1, -1); |
| jump continue; |
| } |
| m += a; |
| @continue; |
| } while(csv != ""); |
| // postcondition: length(s) = 0 |
| return l + m; |
| } |
| |
| /////////////////////////////////////////////////////////////////////////// |
| // Copyright (C) 2015 Wizardry and Steamworks - License: GNU GPLv3 // |
| /////////////////////////////////////////////////////////////////////////// |
| string wasListToCSV(list l) { |
| list v = []; |
| do { |
| string a = llDumpList2String( |
| llParseStringKeepNulls( |
| llList2String( |
| l, |
| 0 |
| ), |
| ["\""], |
| [] |
| ), |
| "\"\"" |
| ); |
| if(llParseStringKeepNulls( |
| a, |
| [" ", ",", "\n", "\""], [] |
| ) != |
| (list) a |
| ) a = "\"" + a + "\""; |
| v += a; |
| l = llDeleteSubList(l, 0, 0); |
| } while(l != []); |
| return llDumpList2String(v, ","); |
| } |
| |
| /////////////////////////////////////////////////////////////////////////// |
| // Copyright (C) 2015 Wizardry and Steamworks - License: GNU GPLv3 // |
| /////////////////////////////////////////////////////////////////////////// |
| // unescapes a string in conformance with RFC1738 |
| string wasURLUnescape(string i) { |
| return llUnescapeURL( |
| llDumpList2String( |
| llParseString2List( |
| llDumpList2String( |
| llParseString2List( |
| i, |
| ["+"], |
| [] |
| ), |
| " " |
| ), |
| ["%0D%0A"], |
| [] |
| ), |
| "\n" |
| ) |
| ); |
| } |
| |
| /////////////////////////////////////////////////////////////////////////// |
| // Copyright (C) 2017 Wizardry and Steamworks - License: GNU GPLv3 // |
| /////////////////////////////////////////////////////////////////////////// |
| list wasSetIntersect(list a, list b) { |
| if(llGetListLength(a) == 0) return []; |
| string i = llList2String(a, 0); |
| a = llDeleteSubList(a, 0, 0); |
| if(llListFindList(b, (list)i) == -1) |
| return wasSetIntersect(a, b); |
| return i + wasSetIntersect(a, b); |
| } |
| |
| // configuration data |
| string configuration = ""; |
| // callback URL |
| string URL = ""; |
| // store message over state. |
| string data = ""; |
| string version = ""; |
| string firstname = ""; |
| string lastname = ""; |
| string jump_state = ""; |
| |
| default { |
| state_entry() { |
| llOwnerSay("[Stitch] Starting..."); |
| llSetTimerEvent(10); |
| } |
| link_message(integer sender, integer num, string message, key id) { |
| if(id != "configuration") return; |
| llOwnerSay("[Stitch] Got configuration..."); |
| configuration = message; |
| state listen_group; |
| } |
| timer() { |
| llOwnerSay("[Stitch] Requesting configuration..."); |
| llMessageLinked(LINK_THIS, 0, "configuration", NULL_KEY); |
| } |
| on_rez(integer num) { |
| llResetScript(); |
| } |
| changed(integer change) { |
| if((change & CHANGED_INVENTORY) || |
| (change & CHANGED_REGION_START) || |
| (change & CHANGED_OWNER)) { |
| llResetScript(); |
| } |
| } |
| state_exit() { |
| llSetTimerEvent(0); |
| } |
| } |
| |
| state listen_group { |
| state_entry() { |
| // DEBUG |
| llOwnerSay("[Stitch] Waiting for group messages..."); |
| } |
| link_message(integer sender, integer num, string message, key id) { |
| // We only care about notifications now. |
| if(id != "notification") |
| return; |
| |
| // This script only processes group notifications. |
| if(wasKeyValueGet("type", message) != "group" && |
| wasKeyValueGet("type", message) != "login") |
| return; |
| |
| // Process login notification. |
| if(wasKeyValueGet("type", message) == "login") { |
| string action = wasKeyValueGet("action", message); |
| string loginVersion = wasKeyValueGet("version", message); |
| if(action == "logout") { |
| version = loginVersion; |
| return; |
| } |
| if(action == "login" && loginVersion != version) { |
| data = "I have been stitched to version v" + loginVersion; |
| version = loginVersion; |
| state tell; |
| } |
| // Unknown login action. |
| return; |
| } |
| |
| // Get the sent message. |
| data = wasURLUnescape( |
| wasKeyValueGet( |
| "message", |
| message |
| ) |
| ); |
| |
| // Check if this is an eggdrop command. |
| if(llGetSubString(data, 0, 0) != |
| wasKeyValueGet("command", configuration)) |
| return; |
| |
| // Check if the command matches the current module. |
| list command = llParseString2List(data, [" "], []); |
| if(llList2String(command, 0) != |
| wasKeyValueGet("command", configuration) + "stitch") |
| return; |
| |
| // Remove command. |
| command = llDeleteSubList(command, 0, 0); |
| |
| firstname = wasKeyValueGet("firstname", message); |
| lastname = wasKeyValueGet("lastname", message); |
| |
| if(firstname == "" || lastname == "") { |
| data = "And who would yarr be?"; |
| state tell; |
| } |
| |
| // Dump the rest of the message. |
| data = llDumpList2String(command, " "); |
| |
| // Get an URL. |
| state url; |
| } |
| on_rez(integer num) { |
| llResetScript(); |
| } |
| changed(integer change) { |
| if((change & CHANGED_INVENTORY) || |
| (change & CHANGED_REGION_START) || |
| (change & CHANGED_OWNER)) { |
| llResetScript(); |
| } |
| } |
| } |
| |
| state url { |
| state_entry() { |
| // DEBUG |
| llOwnerSay("[Stitch] Requesting URL..."); |
| llRequestURL(); |
| } |
| http_request(key id, string method, string body) { |
| if(method != URL_REQUEST_GRANTED) return; |
| URL = body; |
| // DEBUG |
| llOwnerSay("[Stitch] Got URL..."); |
| state get_caller_roles; |
| } |
| on_rez(integer num) { |
| llResetScript(); |
| } |
| changed(integer change) { |
| if((change & CHANGED_INVENTORY) || |
| (change & CHANGED_REGION_START) || |
| (change & CHANGED_OWNER)) { |
| llResetScript(); |
| } |
| } |
| } |
| |
| state get_caller_roles { |
| state_entry() { |
| // DEBUG |
| llOwnerSay("[Stitch] Searching for caller..."); |
| llInstantMessage( |
| wasKeyValueGet( |
| "corrade", |
| configuration |
| ), |
| wasKeyValueEncode( |
| [ |
| "command", "getmemberroles", |
| "group", wasURLEscape( |
| wasKeyValueGet( |
| "group", |
| configuration |
| ) |
| ), |
| "password", wasURLEscape( |
| wasKeyValueGet( |
| "password", |
| configuration |
| ) |
| ), |
| "firstname", firstname, |
| "lastname", lastname, |
| "callback", wasURLEscape(URL) |
| ] |
| ) |
| ); |
| llSetTimerEvent(60); |
| } |
| http_request(key id, string method, string body) { |
| llHTTPResponse(id, 200, "OK"); |
| if(wasKeyValueGet("command", body) != "getmemberroles" || |
| wasKeyValueGet("success", body) != "True") { |
| // DEBUG |
| llOwnerSay("[Stitch] Unable to get member roles: " + |
| wasURLUnescape( |
| wasKeyValueGet("error", body) |
| ) |
| ); |
| llReleaseURL(URL); |
| state listen_group; |
| } |
| |
| // Dump the roles to a list. |
| list roles = wasCSVToList( |
| wasURLUnescape( |
| wasKeyValueGet("data", body) |
| ) |
| ); |
| |
| if(llGetListLength( |
| wasSetIntersect(roles, |
| wasCSVToList( |
| wasKeyValueGet( |
| "admin roles", configuration |
| ) |
| ) |
| ) |
| ) == 0) { |
| data = "You ain't got the cojones!"; |
| llReleaseURL(URL); |
| state tell; |
| } |
| |
| list command = llParseString2List(data, [" "], []); |
| |
| version = llList2String(command, 0); |
| |
| // GC |
| command = []; |
| |
| if(version == "") |
| version = "\"latest\""; |
| |
| // Announce stitching process. |
| data = "Stitching to: " + version; |
| jump_state = "stitch"; |
| state tell; |
| } |
| timer() { |
| llReleaseURL(URL); |
| state listen_group; |
| } |
| on_rez(integer num) { |
| llResetScript(); |
| } |
| changed(integer change) { |
| if((change & CHANGED_INVENTORY) || |
| (change & CHANGED_REGION_START) || |
| (change & CHANGED_OWNER)) { |
| llResetScript(); |
| } |
| } |
| state_exit() { |
| llSetTimerEvent(0); |
| } |
| } |
| |
| state stitch { |
| state_entry() { |
| // DEBUG |
| llOwnerSay("[Stitch] Stitching..."); |
| llInstantMessage( |
| wasKeyValueGet( |
| "corrade", |
| configuration |
| ), |
| wasKeyValueEncode( |
| [ |
| "command", "stitch", |
| "group", wasURLEscape( |
| wasKeyValueGet( |
| "group", |
| configuration |
| ) |
| ), |
| "password", wasURLEscape( |
| wasKeyValueGet( |
| "password", |
| configuration |
| ) |
| ), |
| "action", "stitch", |
| "version", version, |
| "callback", wasURLEscape(URL) |
| ] |
| ) |
| ); |
| llSetTimerEvent(60); |
| } |
| http_request(key id, string method, string body) { |
| llHTTPResponse(id, 200, "OK"); |
| llReleaseURL(URL); |
| if(wasKeyValueGet("command", body) != "stitch" || |
| wasKeyValueGet("success", body) != "True") { |
| // DEBUG |
| llOwnerSay("[Stitch] Unable to stitch: " + |
| wasURLUnescape( |
| wasKeyValueGet("error", body) |
| ) |
| ); |
| state listen_group; |
| } |
| |
| // Corrade proceeds with termination - cannot (should not) announce via "tell". |
| state listen_group; |
| } |
| timer() { |
| llReleaseURL(URL); |
| state listen_group; |
| } |
| on_rez(integer num) { |
| llResetScript(); |
| } |
| changed(integer change) { |
| if((change & CHANGED_INVENTORY) || |
| (change & CHANGED_REGION_START) || |
| (change & CHANGED_OWNER)) { |
| llResetScript(); |
| } |
| } |
| state_exit() { |
| llSetTimerEvent(0); |
| } |
| } |
| |
| state tell { |
| state_entry() { |
| // DEBUG |
| llOwnerSay("[Stitch] Sending to group."); |
| llInstantMessage( |
| wasKeyValueGet( |
| "corrade", |
| configuration |
| ), |
| wasKeyValueEncode( |
| [ |
| "command", "tell", |
| "group", wasURLEscape( |
| wasKeyValueGet( |
| "group", |
| configuration |
| ) |
| ), |
| "password", wasURLEscape( |
| wasKeyValueGet( |
| "password", |
| configuration |
| ) |
| ), |
| "entity", "group", |
| "message", wasURLEscape(data) |
| ] |
| ) |
| ); |
| |
| // jump table |
| string nextState = jump_state; |
| jump_state = ""; |
| if(nextState == "stitch") |
| state stitch; |
| state listen_group; |
| } |
| } |
