| /source/eggdrop/survey.lsl |
|---|
| @@ -0,0 +1,574 @@ |
|---|
| /////////////////////////////////////////////////////////////////////////// |
| // Copyright (C) Wizardry and Steamworks 2016 - License: GNU GPLv3 // |
| /////////////////////////////////////////////////////////////////////////// |
| // |
| // A fortune module for Corrade Eggdrop. |
| // |
| /////////////////////////////////////////////////////////////////////////// |
| |
| /////////////////////////////////////////////////////////////////////////// |
| // Copyright (C) 2015 Wizardry and Steamworks - License: CC BY 2.0 // |
| /////////////////////////////////////////////////////////////////////////// |
| string wasKeyValueGet(string k, string data) { |
| if(llStringLength(data) == 0) return ""; |
| if(llStringLength(k) == 0) return ""; |
| list a = llParseStringKeepNulls(data, ["&", "="], []); |
| integer i = llListFindList(llList2ListStrided(a, 0, -1, 2), [ k ]); |
| if(i != -1) return llList2String(a, 2*i+1); |
| return ""; |
| } |
| |
| /////////////////////////////////////////////////////////////////////////// |
| // Copyright (C) 2013 Wizardry and Steamworks - License: GNU GPLv3 // |
| /////////////////////////////////////////////////////////////////////////// |
| string wasKeyValueEncode(list data) { |
| list k = llList2ListStrided(data, 0, -1, 2); |
| list v = llList2ListStrided(llDeleteSubList(data, 0, 0), 0, -1, 2); |
| data = []; |
| do { |
| data += llList2String(k, 0) + "=" + llList2String(v, 0); |
| k = llDeleteSubList(k, 0, 0); |
| v = llDeleteSubList(v, 0, 0); |
| } while(llGetListLength(k) != 0); |
| return llDumpList2String(data, "&"); |
| } |
| |
| /////////////////////////////////////////////////////////////////////////// |
| // Copyright (C) 2011 Wizardry and Steamworks - License: GNU GPLv3 // |
| /////////////////////////////////////////////////////////////////////////// |
| // http://was.fm/secondlife/wanderer |
| vector wasCirclePoint(float radius) { |
| float x = llPow(-1, 1 + (integer) llFrand(2)) * llFrand(radius*2); |
| float y = llPow(-1, 1 + (integer) llFrand(2)) * llFrand(radius*2); |
| if(llPow(x,2) + llPow(y,2) <= llPow(radius,2)) |
| return <x, y, 0>; |
| return wasCirclePoint(radius); |
| } |
| |
| /////////////////////////////////////////////////////////////////////////// |
| // Copyright (C) 2015 Wizardry and Steamworks - License: GNU GPLv3 // |
| /////////////////////////////////////////////////////////////////////////// |
| // escapes a string in conformance with RFC1738 |
| string wasURLEscape(string i) { |
| string o = ""; |
| do { |
| string c = llGetSubString(i, 0, 0); |
| i = llDeleteSubString(i, 0, 0); |
| if(c == "") jump continue; |
| if(c == " ") { |
| o += "+"; |
| jump continue; |
| } |
| if(c == "\n") { |
| o += "%0D" + llEscapeURL(c); |
| jump continue; |
| } |
| o += llEscapeURL(c); |
| @continue; |
| } while(i != ""); |
| return o; |
| } |
| |
| /////////////////////////////////////////////////////////////////////////// |
| // Copyright (C) 2015 Wizardry and Steamworks - License: GNU GPLv3 // |
| /////////////////////////////////////////////////////////////////////////// |
| list wasCSVToList(string csv) { |
| list l = []; |
| list s = []; |
| string m = ""; |
| do { |
| string a = llGetSubString(csv, 0, 0); |
| csv = llDeleteSubString(csv, 0, 0); |
| if(a == ",") { |
| if(llList2String(s, -1) != "\"") { |
| l += m; |
| m = ""; |
| jump continue; |
| } |
| m += a; |
| jump continue; |
| } |
| if(a == "\"" && llGetSubString(csv, 0, 0) == a) { |
| m += a; |
| csv = llDeleteSubString(csv, 0, 0); |
| jump continue; |
| } |
| if(a == "\"") { |
| if(llList2String(s, -1) != a) { |
| s += a; |
| jump continue; |
| } |
| s = llDeleteSubList(s, -1, -1); |
| jump continue; |
| } |
| m += a; |
| @continue; |
| } while(csv != ""); |
| // postcondition: length(s) = 0 |
| return l + m; |
| } |
| |
| /////////////////////////////////////////////////////////////////////////// |
| // Copyright (C) 2015 Wizardry and Steamworks - License: GNU GPLv3 // |
| /////////////////////////////////////////////////////////////////////////// |
| string wasListToCSV(list l) { |
| list v = []; |
| do { |
| string a = llDumpList2String( |
| llParseStringKeepNulls( |
| llList2String( |
| l, |
| 0 |
| ), |
| ["\""], |
| [] |
| ), |
| "\"\"" |
| ); |
| if(llParseStringKeepNulls( |
| a, |
| [" ", ",", "\n", "\""], [] |
| ) != |
| (list) a |
| ) a = "\"" + a + "\""; |
| v += a; |
| l = llDeleteSubList(l, 0, 0); |
| } while(l != []); |
| return llDumpList2String(v, ","); |
| } |
| |
| /////////////////////////////////////////////////////////////////////////// |
| // Copyright (C) 2015 Wizardry and Steamworks - License: GNU GPLv3 // |
| /////////////////////////////////////////////////////////////////////////// |
| // unescapes a string in conformance with RFC1738 |
| string wasURLUnescape(string i) { |
| return llUnescapeURL( |
| llDumpList2String( |
| llParseString2List( |
| llDumpList2String( |
| llParseString2List( |
| i, |
| ["+"], |
| [] |
| ), |
| " " |
| ), |
| ["%0D%0A"], |
| [] |
| ), |
| "\n" |
| ) |
| ); |
| } |
| |
| // configuration data |
| string configuration = ""; |
| // callback URL |
| string URL = ""; |
| // store message over state. |
| string data = ""; |
| |
| key queryID = NULL_KEY; |
| string region = ""; |
| |
| string teleport_continue = ""; |
| |
| default { |
| state_entry() { |
| llOwnerSay("[Survey] Starting module..."); |
| llSetTimerEvent(10); |
| } |
| link_message(integer sender, integer num, string message, key id) { |
| if(id != "configuration") return; |
| llOwnerSay("[Survey] Got configuration..."); |
| configuration = message; |
| state listen_group; |
| } |
| timer() { |
| llOwnerSay("[Survey] Requesting configuration..."); |
| llMessageLinked(LINK_THIS, 0, "configuration", NULL_KEY); |
| } |
| on_rez(integer num) { |
| llResetScript(); |
| } |
| changed(integer change) { |
| if((change & CHANGED_INVENTORY) || |
| (change & CHANGED_REGION_START) || |
| (change & CHANGED_OWNER)) { |
| llResetScript(); |
| } |
| } |
| state_exit() { |
| llSetTimerEvent(0); |
| } |
| } |
| |
| state listen_group { |
| state_entry() { |
| // DEBUG |
| llOwnerSay("[Survey] Waiting for group messages..."); |
| } |
| link_message(integer sender, integer num, string message, key id) { |
| // We only care about notifications now. |
| if(id != "notification") |
| return; |
| |
| // This script only processes group notifications. |
| if(wasKeyValueGet("type", message) != "group" || |
| (wasKeyValueGet("type", message) == "group" && |
| wasURLUnescape(wasKeyValueGet("group", message)) != |
| wasKeyValueGet("group", configuration))) |
| return; |
| |
| // Get the sent message. |
| data = wasURLUnescape( |
| wasKeyValueGet( |
| "message", |
| message |
| ) |
| ); |
| |
| // Check if this is an eggdrop command. |
| if(llGetSubString(data, 0, 0) != |
| wasKeyValueGet("command", configuration)) |
| return; |
| |
| // Check if the command matches the current module. |
| list command = llParseString2List(data, [" "], []); |
| if(llList2String(command, 0) != |
| wasKeyValueGet("command", configuration) + "survey") |
| return; |
| |
| // Remove command. |
| command = llDeleteSubList(command, 0, 0); |
| |
| // Store the region name. |
| region = llStringTrim( |
| llDumpList2String( |
| command, " " |
| ), |
| STRING_TRIM |
| ); |
| |
| if(llStringLength(region) == 0) { |
| data = "Must specify a region name"; |
| state tell; |
| } |
| |
| llOwnerSay("[Survey] Checking region..."); |
| queryID = llRequestSimulatorData(region, DATA_SIM_STATUS); |
| } |
| dataserver(key query_id, string data) { |
| if(query_id != queryID) |
| return; |
| |
| if(data == "unknown") { |
| data = "Region not found or in unknown state."; |
| state tell; |
| } |
| |
| if(data == "down") { |
| data = "Region is down."; |
| state tell; |
| } |
| |
| if(data == "starting") { |
| data = "Region is currently starting."; |
| state tell; |
| } |
| |
| if(data == "stopping") { |
| data = "Region is stopping."; |
| state tell; |
| } |
| |
| if(data == "crashed") { |
| data = "Region has crashed."; |
| state tell; |
| } |
| |
| // Teleport. |
| teleport_continue = "stats_trampoline"; |
| state teleport_trampoline; |
| } |
| on_rez(integer num) { |
| llResetScript(); |
| } |
| changed(integer change) { |
| if((change & CHANGED_INVENTORY) || |
| (change & CHANGED_REGION_START) || |
| (change & CHANGED_OWNER)) { |
| llResetScript(); |
| } |
| } |
| } |
| |
| state teleport_trampoline { |
| state_entry() { |
| // DEBUG |
| llOwnerSay("Sleeping..."); |
| llSetTimerEvent(3); |
| } |
| timer() { |
| state teleport; |
| } |
| on_rez(integer num) { |
| llResetScript(); |
| } |
| changed(integer change) { |
| if((change & CHANGED_INVENTORY) || |
| (change & CHANGED_REGION_START) || |
| (change & CHANGED_OWNER)) { |
| llResetScript(); |
| } |
| } |
| state_exit() { |
| llSetTimerEvent(0); |
| } |
| } |
| |
| state teleport { |
| state_entry() { |
| llOwnerSay("[Survey] Teleporting..."); |
| llInstantMessage( |
| wasKeyValueGet( |
| "corrade", |
| configuration |
| ), |
| wasKeyValueEncode( |
| [ |
| "command", "teleport", |
| "group", wasURLEscape( |
| wasKeyValueGet( |
| "group", |
| configuration |
| ) |
| ), |
| "password", wasURLEscape( |
| wasKeyValueGet( |
| "password", |
| configuration |
| ) |
| ), |
| "entity", "region", |
| "region", wasURLEscape(region), |
| "position", wasURLEscape("<128, 128, 4096>"), |
| "callback", wasURLEscape( |
| wasKeyValueGet( |
| "URL", |
| configuration |
| ) |
| ) |
| ] |
| ) |
| ); |
| |
| llSetTimerEvent(60); |
| } |
| link_message(integer sender, integer num, string body, key id) { |
| // Only process callbacks for the database command. |
| if(id != "callback" || wasKeyValueGet("command", body) != "teleport") |
| return; |
| |
| if(wasKeyValueGet("success", body) != "True") { |
| // DEBUG |
| llOwnerSay("[Survey] Teleport failed: " + |
| wasURLUnescape( |
| wasKeyValueGet("error", body) |
| ) |
| ); |
| state listen_group; |
| } |
| |
| if(teleport_continue == "stats_trampoline") |
| state stats_trampoline; |
| |
| if(teleport_continue == "tell") |
| state tell; |
| |
| llOwnerSay("[Survey] Jump tables corrupt, please contact vendor."); |
| llResetScript(); |
| } |
| timer() { |
| data = "Teleport timed out..."; |
| state tell; |
| } |
| on_rez(integer num) { |
| llResetScript(); |
| } |
| changed(integer change) { |
| if((change & CHANGED_INVENTORY) || |
| (change & CHANGED_REGION_START) || |
| (change & CHANGED_OWNER)) { |
| llResetScript(); |
| } |
| } |
| state_exit() { |
| llSetTimerEvent(0); |
| } |
| } |
| |
| state stats_trampoline { |
| state_entry() { |
| // DEBUG |
| llOwnerSay("Sleeping..."); |
| llSetTimerEvent(3); |
| } |
| timer() { |
| state stats; |
| } |
| on_rez(integer num) { |
| llResetScript(); |
| } |
| changed(integer change) { |
| if((change & CHANGED_INVENTORY) || |
| (change & CHANGED_REGION_START) || |
| (change & CHANGED_OWNER)) { |
| llResetScript(); |
| } |
| } |
| state_exit() { |
| llSetTimerEvent(0); |
| } |
| } |
| |
| state stats { |
| state_entry() { |
| llSleep(10); |
| llOwnerSay("[Survey] Getting region statistics..."); |
| llInstantMessage( |
| wasKeyValueGet( |
| "corrade", |
| configuration |
| ), |
| wasKeyValueEncode( |
| [ |
| "command", "getregiondata", |
| "group", wasURLEscape( |
| wasKeyValueGet( |
| "group", |
| configuration |
| ) |
| ), |
| "password", wasURLEscape( |
| wasKeyValueGet( |
| "password", |
| configuration |
| ) |
| ), |
| "data", wasListToCSV( |
| [ |
| "Stats.LastLag", |
| "Stats.Agents", |
| "Stats.Dilation", |
| "Stats.FPS", |
| "Stats.ActiveScripts", |
| "Stats.ScriptTime", |
| "Stats.Objects", |
| "Stats.PhysicsFPS", |
| "Stats.ScriptTime" |
| ] |
| ), |
| "callback", wasURLEscape( |
| wasKeyValueGet( |
| "URL", |
| configuration |
| ) |
| ) |
| ] |
| ) |
| ); |
| |
| llSetTimerEvent(300); |
| } |
| link_message(integer sender, integer num, string body, key id) { |
| // Only process callbacks for the database command. |
| if(id != "callback" || wasKeyValueGet("command", body) != "getregiondata") |
| return; |
| |
| if(wasKeyValueGet("success", body) != "True") { |
| // DEBUG |
| llOwnerSay("[Survey] Stats failed: " + |
| wasURLUnescape( |
| wasKeyValueGet("error", body) |
| ) |
| ); |
| state listen_group; |
| } |
| |
| list stat = wasCSVToList( |
| wasURLUnescape( |
| wasKeyValueGet( |
| "data", |
| body |
| ) |
| ) |
| ); |
| |
| data = llDumpList2String(stat, " "); |
| |
| // Go home. |
| region = wasKeyValueGet( |
| "home region", |
| configuration |
| ); |
| teleport_continue = "tell"; |
| state teleport_trampoline; |
| } |
| timer() { |
| // Go home. |
| region = wasKeyValueGet( |
| "home region", |
| configuration |
| ); |
| data = "Fetching data timed out..."; |
| teleport_continue = "tell"; |
| state teleport_trampoline; |
| } |
| on_rez(integer num) { |
| llResetScript(); |
| } |
| changed(integer change) { |
| if((change & CHANGED_INVENTORY) || |
| (change & CHANGED_REGION_START) || |
| (change & CHANGED_OWNER)) { |
| llResetScript(); |
| } |
| } |
| state_exit() { |
| llSetTimerEvent(0); |
| } |
| } |
| |
| state tell { |
| state_entry() { |
| // DEBUG |
| llOwnerSay("[Survey] Sending to group."); |
| llInstantMessage( |
| wasKeyValueGet( |
| "corrade", |
| configuration |
| ), |
| wasKeyValueEncode( |
| [ |
| "command", "tell", |
| "group", wasURLEscape( |
| wasKeyValueGet( |
| "group", |
| configuration |
| ) |
| ), |
| "password", wasURLEscape( |
| wasKeyValueGet( |
| "password", |
| configuration |
| ) |
| ), |
| "entity", "group", |
| "message", wasURLEscape(data) |
| ] |
| ) |
| ); |
| state listen_group; |
| } |
| } |
